*BELOW ARE THE SYNTAX SOLUTIONS TO THE 'TRYS' FROM THE NIHPS WORKSHOP. 
*PLEASE SUBSTITUTE YOUR OWN FILE LOCATIONS FOR THOSE IN THE SYNTAX.


* TRY KHHRESP example .
GET  FILE='C:\nihps\nidata\khhresp.sav'.
FILTER OFF.
USE ALL.
SELECT IF(khsowr1 > 0 & khsowr2 > 0).
EXECUTE .
cross  khsowr1 by khsowr2.
SORT CASES BY  khid (A) khsowr1 (A).
save outfile = "c:\nihown.sav" /keep khid khsowr1 khsowr2.
GET  FILE='C:\nihown.sav'.
MATCH FILES /FILE=* /RENAME  khsowr1=kpno khsowr2=kopno
 /TABLE='C:\nihps\nidata\kegoalt.sav' /BY khid kpno kopno.
EXECUTE.
cro krel by ksex.

*  TRY kindsamp example .
GET  FILE='C:\nihps\nidata\kindsamp.sav'.
fre khhmem .
compute memres = 0.
compute memabs = 0.
execute.
IF (khhmem = 1) memres = 1 .
IF (khhmem = 2) memabs = 1 .
EXECUTE .
AGGREGATE  /OUTFILE=*  /BREAK=khid
  /memreshh = SUM(memres) /memabshh = SUM(memabs)  /nop=N.
FREQUENCIES  VARIABLES=memreshh memabshh nop  /ORDER=  ANALYSIS .

* TRY kindall example kindresp example .
GET  FILE='C:\nihps\nidata\kindall.sav'.
fre kivfio kivfho.
cross kivfio by kivfho.
compute indint = 0.
compute indref = 0.
compute indkid = 0.
execute.
IF (kivfio = 1) indint = 1 .
IF (kivfio = 2) indint = 1 .
IF (kivfio = 10) indref = 1 .
IF (kivfio = 11) indref= 1 .
IF (kivfio = 20) indkid = 1 .
EXECUTE .
AGGREGATE  /OUTFILE=*  /BREAK=khid
  /hhindint = SUM(indint) /hhindref = SUM(indref) /hhindkid = SUM(indkid)  /nopihh=N.
COMPUTE allint = nopihh - (hhindint + hhindkid) .
EXECUTE .
FREQUENCIES  VARIABLES=hhindint hhindref hhindkid nopihh allint  /ORDER=  ANALYSIS .

* TRY kindall example kindresp example .
GET  FILE='C:\nihps\nidata\kindall.sav'.
RECODE  kivfio  (20=3)  (1 thru 2=1)  (10 thru 11=2)  INTO  intout .
VARIABLE LABELS intout 'interview outcome'.
EXECUTE .
MEANS  TABLES=kage12  BY intout  /CELLS MEAN COUNT STDDEV  .

* TRY  Construct a file with a subject's age and the age of their parents.
GET  FILE='C:\nihps\nidata\kindall.sav'.
sort cases by khid kpno.
save outfile = 'c:\niage.sav' /keep khid kpno kage12.
rename variables (kpno kage12 khgfno khgmno = kidpno kidage papno mapno).
save outfile = 'c:\niallage.sav' /keep khid kidpno kidage papno mapno.
sort cases by khid papno.
save outfile = 'c:\nipaage.sav' /keep khid   papno .
sort cases by khid mapno.
save outfile = 'c:\nimaage.sav' /keep khid   mapno .

get file = 'c:\nipaage.sav'.
FILTER OFF.
USE ALL.
SELECT IF(papno > 0).
EXECUTE .
AGGREGATE  /OUTFILE=*  /BREAK=khid papno  /N_BREAK=N.

MATCH FILES /FILE=* /TABLE='C:\niage.sav' /RENAME  kpno=papno /BY khid papno.
EXECUTE.
rename variables ( kage12 =   paage ).
save outfile = 'c:\nipaage.sav' .

get file = 'c:\nimaage.sav'.
FILTER OFF.
USE ALL.
SELECT IF(mapno > 0).
EXECUTE .
AGGREGATE  /OUTFILE=*  /BREAK=khid mapno /N_BREAK=N.
MATCH FILES /FILE=* /TABLE='C:\niage.sav' /RENAME  kpno=mapno /BY khid mapno.
EXECUTE.
rename variables ( kage12 =   maage ).
save outfile = 'c:\nimaage.sav' .

get file = 'c:\niallage.sav' .
SORT CASES BY  khid (A) papno (A) .
MATCH FILES /FILE=* /TABLE='C:\nipaage.sav' /BY khid papno.
EXECUTE.
SORT CASES BY  khid (A) mapno (A) .
MATCH FILES /FILE=* /TABLE='C:\nimaage.sav' /BY khid mapno.
EXECUTE.
COMPUTE diffkam = maage -   kidage .
COMPUTE diffkap = paage -   kidage .
COMPUTE diffpam = paage -   maage .
EXECUTE .
DESCRIPTIVES  VARIABLES=diffkam diffkap diffpam  /STATISTICS=MEAN STDDEV MIN MAX .


* TRY  How much Child Benefit did people receive from Sept 2000 to Aug 2001? .

GET  FILE='C:\nihps\nidata\kincome.sav'.
USE ALL.
SELECT IF(kficode = 35).
EXECUTE .
COMPUTE kidben = kfim09l + kfim10l + kfim11l + kfim12l + kfim01t + kfim02t +
  kfim03t + kfim04t + kfim05t + kfim06t + kfim07t + kfim08t .
EXECUTE .
DESCRIPTIVES  VARIABLES=kidben  /STATISTICS=MEAN STDDEV MIN MAX .


* TRY  How much Child Benefit did each Household receive from Sept 2000 to Aug 2001? .
AGGREGATE  /OUTFILE=*  /BREAK=khid  /hhkidben = SUM(kidben)  /noprcb=N.
FREQUENCIES  VARIABLES=noprcb  /ORDER=  ANALYSIS .
DESCRIPTIVES  VARIABLES=hhkidben  /STATISTICS=MEAN STDDEV MIN MAX .